IPアドレスリストからFTPGETするバッチ

@echo off
setlocal enabledelayedexpansion

REM ////////////////////////////////////
REM 2015/12/7 marujx
REM ////////////////////////////////////

for /F "delims=." %%a in ('echo %DATE:/=%%TIME::=%') do SET today=%%a

REM IPアドレスリストファイル名を指定
set file_list=listfile.txt

REM 結果ファイル
set fname=%today%result.txt

REM FTP結果ファイル
set ftpfname=ftpresult.txt

REM FTPのスクリプトファイル
set ftpscript=ftpexec.ftp

REM カレントディレクトリ（取得先ディレクトリ　例：set CURDIR=maru）
set CURDIR=\

REM リモートディレクトリ（cd先 cdしない場合は.　DATAへcdする場合は：set REMDIR=DATA）
set REMDIR=.

REM 送信ファイル
set DATAFILE1=nosleep.txt

REM アカウント
set USERNAME=Administrator
set PASSWORD=p@ssw0rd

REM 成功判定コード（FTPコード）
set SUCCESSCODE=^"226 "

 
FOR /F "delims=" %%a IN (%file_list%) DO (
	echo ------------------------------------------------------------->>%fname%
	echo 開始時刻：!date! !time!>>%fname%
	echo %%a　へFTPを実施中・・・
	echo 対象アドレス：%%a>>%fname%
	REM -------------FTPスクリプトファイル書き込み------------------
	echo open %%a> %ftpscript%
	echo %USERNAME%>> %ftpscript%
	echo %PASSWORD%>> %ftpscript%
	echo bin>> %ftpscript%
	echo cd %REMDIR%>> %ftpscript%
	echo get %DATAFILE1% %%a_%DATAFILE1%>> %ftpscript%
	echo bye>> %ftpscript%
	REM -------------FTP実行-------------------
	ftp -s:%ftpscript% > %ftpfname% 2>&1
	type %ftpfname% >> %fname%
	find %SUCCESSCODE% %ftpfname% 
	if "!errorlevel!"=="0" (
		echo %%aからのファイル取得に成功しました
		echo %%aからのファイル取得に成功しました>>%fname%
	) else (
		echo %%aからのファイル取得に失敗しました
		echo %%aからのファイル取得に失敗しました>>%fname%
	)
	echo 終了時刻：!date! !time!>>%fname%
	echo ------------------------------------------------------------->>%fname%
	)
 
%fname%
 
Pause